Move project to CMake (#781)

* Move to cmake

* Move sources to source_groups and ditch more old VS files

* Add BuildVer.h generation

* Break out cmake source lists to platforms

* Don't copy swf files

* Revert audio changes from merge

* Add platform defines

* Match MSBuild flags

* Move BuildVer.h to common include and fix rebuild issue

* Seperate projects properly

* Exclude more files and make sure GameHDD exists

* Missing line

* Remove remaining VS project files

* Update readme and actions

* Use incremental LTCG

* Update workflows

* Update build workflows and output folder

* Disable vcpkg checks

* Force MSVC

* Use precompiled headers

* Only use PCH for cpp

* Exclude compat_shims from PCH

* Handle per-platform source includes

* Copy only current platform media

* Define Iggy libs per platform

* Fix EnsureGameHDD check

* Only set WIN32_EXECUTABLE on Windows

* Correct Iggy libs path

* Remove include of terrain_MipmapLevel

* Correct path to xsb/xwb

* Implement copilot suggestions

* Add clang flags (untested)

* Fix robocopy error checking

* Update documentation

* Drop CMakePresets.json version as we dont use v6 features

* Always cleanup artifacts in nightly even if some builds fail

* Re-work compiler target options

* Move newer iggy dll into redist and cleanup

* Fix typos

* Remove 'Source Files' from all source groups

* Remove old ps1 build scripts

cmake/CopyFolderScript.cmake

@@ -0,0 +1,70 @@
+# Cross-platform recursive copy with exclusion support
+#
+# Required:
+#   COPY_SOURCE   – source directory
+#   COPY_DEST     – destination directory
+#
+# Optional:
+#   EXCLUDE_FILES – pipe-separated file patterns to exclude
+#   EXCLUDE_FOLDERS – pipe-separated folder patterns to exclude
+
+if(NOT COPY_SOURCE OR NOT COPY_DEST)
+  message(FATAL_ERROR "COPY_SOURCE and COPY_DEST must be set.")
+endif()
+
+# Replace "|" with ";" to convert the exclusion patterns back into a list
+if(EXCLUDE_FILES)
+  string(REPLACE "|" ";" EXCLUDE_FILES "${EXCLUDE_FILES}")
+endif()
+
+if(EXCLUDE_FOLDERS)
+  string(REPLACE "|" ";" EXCLUDE_FOLDERS "${EXCLUDE_FOLDERS}")
+endif()
+
+message(STATUS "Copying from ${COPY_SOURCE} to ${COPY_DEST}")
+
+if(CMAKE_HOST_WIN32)
+  set(robocopy_args
+    "${COPY_SOURCE}" "${COPY_DEST}"
+    /S /MT /R:0 /W:0 /NP
+  )
+
+  if(EXCLUDE_FILES)
+    list(APPEND robocopy_args /XF ${EXCLUDE_FILES})
+  endif()
+
+  if(EXCLUDE_FOLDERS)
+    list(APPEND robocopy_args /XD ${EXCLUDE_FOLDERS})
+  endif()
+
+  execute_process(
+    COMMAND robocopy.exe ${robocopy_args}
+    RESULT_VARIABLE rc
+  )
+
+  if(rc GREATER 7) # Allows for "files copied" and "no files copied" cases, but treats actual errors as failures
+    message(FATAL_ERROR "robocopy failed (exit code ${rc})")
+  endif()
+elseif(CMAKE_HOST_UNIX)
+  set(rsync_args -av)
+
+  foreach(pattern IN LISTS EXCLUDE_FILES)
+    list(APPEND rsync_args "--exclude=${pattern}")
+  endforeach()
+
+  foreach(pattern IN LISTS EXCLUDE_FOLDERS)
+    list(APPEND rsync_args "--exclude=${pattern}")
+  endforeach()
+
+  # Trailing slashes ensure rsync copies contents, not the directory itself
+  execute_process(
+    COMMAND rsync ${rsync_args} "${COPY_SOURCE}/" "${COPY_DEST}/"
+    RESULT_VARIABLE rs
+  )
+
+  if(rs GREATER 0) # Any non-zero exit code indicates an error
+    message(FATAL_ERROR "rsync failed (exit code ${rs})")
+  endif()
+else()
+  message(FATAL_ERROR "Unsupported host platform for asset copying.")
+endif()